It look to me for some strange reason these two lines of code were missing from wwMaint :: wcDLLErrorLog

LOCAL loResponse as wwResponseString
loResponse=CREATE([WWC_RESPONSESTRING])

-Jun

Yes that's a bug but creating a response like that isn't going to fix it.

This does:

FUNCTION wcDLLErrorLog

llDelete = !EMPTY(Request.QueryString(3))

lcFileName = THIS.oServer.cTempFilePath + "wcErrors.txt"

IF llDelete
   lnHandle = FOPEN(lcFileName,2)
   IF lnHandle > 0
	   FCHSIZE(lnHandle,0)
	   FCLOSE(lnHandle)
       THIS.StandardPage("Web Connection DLL Error File was cleared",;
                         "The file was cleared.")
   ELSE
      THIS.StandardPage("Web Connection DLL Error File not Deleted",;
                        "The file could not be deleted - most likely because it's in use. Retry this link a few times.")
   ENDIF 
   RETURN
ENDIF

IF !FILE(lcFileName)
   THIS.ErrorMsg("Error File does not exist",;
                 "This means there are no errors to report")
   RETURN
ENDIF

lcFileText = File2Var(lcFileName)
IF EMPTY(lcFileText)
   THIS.ErrorMsg("No data returned from Web Connection DLL Error File",;
                 "This means either the file is empty, or the file is in use.")
   RETURN
ENDIF


Response.Write(this.Pageheadertemplate("Web Connection DLL Error Log"))

Response.Write("<br>Filename:  " + lcFileName + "<br>")
Response.Write([<a href="] + Request.GetCurrentUrl() + "~Delete" + [">Delete Log</a><br>],"Clear")   
Response.Write("<pre>")
Response.Write(lcFileText)
Response.Write("</pre>")

Response.Write(this.Pagefootertemplate())

ENDFUNC
* wwMaint :: wcErrorFile

Ugh - that code is need of some cleaning up... but the above should work.

+++ Rick ---